cmake_minimum_required(VERSION 3.10)

project(ChargeECS VERSION 1.0)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
set(CMAKE_MODULE_PATH "modules/" ${CMAKE_MODULE_PATH})
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -fsanitize=address")
endif()

find_package(Corrade REQUIRED Main)
find_package(Magnum REQUIRED)
find_package(FLECS REQUIRED)

add_library(ChargeECS SHARED "src/ChargeECS.hpp")

target_link_libraries(ChargeECS PRIVATE Corrade::Main Magnum::Magnum
                                        FLECS::FLECS)

target_include_directories(
  ChargeECS
  PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/lib>
         $<INSTALL_INTERFACE:include>)

# Library
install(
  TARGETS ChargeECS
  EXPORT ChargeECSTargets
  LIBRARY DESTINATION lib
  ARCHIVE DESTINATION lib
  RUNTIME DESTINATION bin)

# include
install(FILES src/ChargeECS.hpp DESTINATION include/Charge)

install(
  EXPORT ChargeECSTargets
  FILE ChargeECSTargets.cmake
  NAMESPACE ChargeECS::
  DESTINATION lib/cmake/ChargeECS)

include(CMakePackageConfigHelpers)

configure_package_config_file(
  ${CMAKE_CURRENT_SOURCE_DIR}/ChargeECSConfig.cmake.in
  "${CMAKE_CURRENT_BINARY_DIR}/ChargeECSConfig.cmake"
  INSTALL_DESTINATION lib/cmake/ChargeECS)

install(FILES "${CMAKE_CURRENT_BINARY_DIR}/ChargeECSConfig.cmake"
        DESTINATION lib/cmake/ChargeECS)